<robotmodel> ::= <tree>

<tree> ::= <element> '\n' [ <tree> ] | '{' '\n' <tree> '\n' '}' '\n'

<element> ::= <comment> | <include> | <part> | <transform> | <joint> | <special>

<part> ::= <point> | 
           <sphere> | <spherewired> | <spheretextured> | 
           <box> | <boxwired> | <boxtextured> | <openbox> |
           <cone> | <coneplate> | <conetextured> | 
           <cylinder> | <cylindertextured> |
           <crossbrace> | 
           <text> |
           <checkerboard> |
           <image> 

<transform> ::= <rotate> | <translate> | <scale> | <homogeneous_transform>

<joint> ::= <rotation_parameter> | <prismatic_parameter> 

<special> ::= <marker> | <label> | <camera> | 
              <forcetorque> | <mass> | 
              <endeffector> | <endeffector_targetpose> | <endeffector_tolabel> | 
              <graspable> | <gripper> 
              

<include> ::= include( <filename> )
<comment> ::= '#' <unparsed text..> | '//' <unparsed text..>

<point> ::= point( <color>, <radius> )
<sphere> ::= sphere( <color>, <width>, <height>, <depth> )
<spherewired> ::= spherewired( <color>, <radius> )
<spheretextured> ::= spheretextured( <color>, <width>, <height>, <depth>, <filename> )
<box> ::= box( <color>, <width>, <height>, <depth> )
<boxwired> ::= boxwired( <color>, <width>, <height>, <depth> )
<boxtextured> ::= boxtextured( <color>, <width>, <height>, <depth>, <filename> )
<openbox> ::= openbox( <color>, <width>, <height>, <depth>, <width-inside> )
<cone> ::= cone( <color>, <width-bottom>, <depth>, <width-top> )
<coneplate> ::= coneplate( <color>, <width-bottom>, <depth>, <width-top> )
<conetextured> ::= cone( <color>, <width-bottom>, <depth>, <width-top>, <filename> )
<cylinder> ::= cylinder( <color>, <radius>, <depth> )
<cylindertextured> ::= cylinder( <color>, <radius>, <depth>, <filename> )
<crossbrace> ::= crossbrace( <color>, <width>, <extra-end>, <extra-end> )
<text> ::= crossbrace( <color>, <text> )
<checkerboard> ::= checkerboard( <color>, <width>, <height>, <faces-x>, <faces-y> )
<image> ::= image( <filename> )

<rotate> ::= rotate( <rx>, <ry>, <rz> )
<translate> ::= translate( <x>, <y>, <z> )
<scale> ::= scale( <sx>, <sy>, <sz> )
<homogeneous_transform> ::= homogeneous_transform( <r11>,<r12>,<r13>,    <t1>, 
                                                   <r21>,<r22>,<r23>,    <t2>,
                                                   <r31>,<r32>,<r33>,    <t3>,
                                                       0,    0,    0,       1 )

<rotation_parameter> ::= rotation_parameter( <name>, <default-value>, <min-value>, <max-value>, <current-value> )
<prismatic_parameter> ::= prismatic_parameter( <name>, <default-value>, <min-value>, <max-value>, <current-value> )

<label> ::= label( <name> )
<marker> ::= marker( <name> ) | marker( <id> )
<camera> ::= camera( <name>, <filename> )
<forcetorque> ::= forcetorque()
<mass> ::= mass( <mass-kg> )
<endeffector> ::= endeffector( <endeff-name> )
<endeffector_targetpose> ::= endeffector_targetpose( <endeff-name> )
<endeffector_tolabel> ::= endeffector_tolabel( <endeff-name>, <target-label-name> )
<graspable> ::= graspable()
<gripper> ::= gripper( <name>, <default-value>, <min-value>, <max-value>, <current-value> )

<color> ::= <named-color> | <rgb-color>
<named-color> ::= silver | darkgrey | grey | red | green | blue | black | white | yellow
<rgb-color> ::= '#'<red><green><blue>
<red> ::= [0-9a-f][0-9a-f]
<green> ::= [0-9a-f][0-9a-f]
<blue> ::= [0-9a-f][0-9a-f]